mirrors/git
1
0
Fork 0
mirror of https://github.com/git/git.git synced 2024-10-31 22:37:54 +01:00
Code Activity

Merge branch 'cc/git-packet-pm'

Browse source 
Parts of a test to drive the long-running content filter interface
has been split into its own module, hopefully to eventually become
reusable.

* cc/git-packet-pm:
  Git/Packet.pm: extract parts of t0021/rot13-filter.pl for reuse
  t0021/rot13-filter: add capability functions
  t0021/rot13-filter: refactor checking final lf
  t0021/rot13-filter: add packet_initialize()
  t0021/rot13-filter: improve error message
  t0021/rot13-filter: improve 'if .. elsif .. else' style
  t0021/rot13-filter: refactor packet reading functions
  t0021/rot13-filter: fix list comparison
This commit is contained in:
Junio C Hamano 2017-11-15 12:14:31 +09:00
commit 563b0610d6
3 changed files with 202 additions and 94 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

168
perl/Git/Packet.pm Normal file
View file

@ -0,0 +1,168 @@
package Git::Packet;
use 5.008;
use strict;
use warnings;
BEGIN {
require Exporter;
if ($] < 5.008003) {
*import = \&Exporter::import;
} else {
# Exporter 5.57 which supports this invocation was
# released with perl 5.8.3
Exporter->import('import');
}
}
our @EXPORT = qw(
packet_compare_lists
packet_bin_read
packet_txt_read
packet_required_key_val_read
packet_bin_write
packet_txt_write
packet_flush
packet_initialize
packet_read_capabilities
packet_read_and_check_capabilities
packet_check_and_write_capabilities
);
our @EXPORT_OK = @EXPORT;
sub packet_compare_lists {
my ($expect, @result) = @_;
my $ix;
if (scalar @$expect != scalar @result) {
return undef;
}
for ($ix = 0; $ix < $#result; $ix++) {
if ($expect->[$ix] ne $result[$ix]) {
return undef;
}
}
return 1;
}
sub packet_bin_read {
my $buffer;
my $bytes_read = read STDIN, $buffer, 4;
if ( $bytes_read == 0 ) {
# EOF - Git stopped talking to us!
return ( -1, "" );
} elsif ( $bytes_read != 4 ) {
die "invalid packet: '$buffer'";
}
my $pkt_size = hex($buffer);
if ( $pkt_size == 0 ) {
return ( 1, "" );
} elsif ( $pkt_size > 4 ) {
my $content_size = $pkt_size - 4;
$bytes_read = read STDIN, $buffer, $content_size;
if ( $bytes_read != $content_size ) {
die "invalid packet ($content_size bytes expected; $bytes_read bytes read)";
}
return ( 0, $buffer );
} else {
die "invalid packet size: $pkt_size";
}
}
sub remove_final_lf_or_die {
my $buf = shift;
unless ( $buf =~ s/\n$// ) {
die "A non-binary line MUST be terminated by an LF.\n"
. "Received: '$buf'";
}
return $buf;
}
sub packet_txt_read {
my ( $res, $buf ) = packet_bin_read();
unless ( $res == -1 or $buf eq '' ) {
$buf = remove_final_lf_or_die($buf);
}
return ( $res, $buf );
}
sub packet_required_key_val_read {
my ( $key ) = @_;
my ( $res, $buf ) = packet_txt_read();
unless ( $res == -1 or ( $buf =~ s/^$key=// and $buf ne '' ) ) {
die "bad $key: '$buf'";
}
return ( $res, $buf );
}
sub packet_bin_write {
my $buf = shift;
print STDOUT sprintf( "%04x", length($buf) + 4 );
print STDOUT $buf;
STDOUT->flush();
}
sub packet_txt_write {
packet_bin_write( $_[0] . "\n" );
}
sub packet_flush {
print STDOUT sprintf( "%04x", 0 );
STDOUT->flush();
}
sub packet_initialize {
my ($name, $version) = @_;
packet_compare_lists([0, $name . "-client"], packet_txt_read()) ||
die "bad initialize";
packet_compare_lists([0, "version=" . $version], packet_txt_read()) ||
die "bad version";
packet_compare_lists([1, ""], packet_bin_read()) ||
die "bad version end";
packet_txt_write( $name . "-server" );
packet_txt_write( "version=" . $version );
packet_flush();
}
sub packet_read_capabilities {
my @cap;
while (1) {
my ( $res, $buf ) = packet_bin_read();
if ( $res == -1 ) {
die "unexpected EOF when reading capabilities";
}
return ( $res, @cap ) if ( $res != 0 );
$buf = remove_final_lf_or_die($buf);
unless ( $buf =~ s/capability=// ) {
die "bad capability buf: '$buf'";
}
push @cap, $buf;
}
}
# Read remote capabilities and check them against capabilities we require
sub packet_read_and_check_capabilities {
my @required_caps = @_;
my ($res, @remote_caps) = packet_read_capabilities();
my %remote_caps = map { $_ => 1 } @remote_caps;
foreach (@required_caps) {
unless (exists($remote_caps{$_})) {
die "required '$_' capability not available from remote" ;
}
}
return %remote_caps;
}
# Check our capabilities we want to advertise against the remote ones
# and then advertise our capabilities
sub packet_check_and_write_capabilities {
my ($remote_caps, @our_caps) = @_;
foreach (@our_caps) {
unless (exists($remote_caps->{$_})) {
die "our capability '$_' is not available from remote"
}
packet_txt_write( "capability=" . $_ );
}
packet_flush();
}
1;

1
perl/Makefile
View file

@ -30,6 +30,7 @@ instdir_SQ = $(subst ','\'',$(prefix)/lib)
modules += Git
modules += Git/I18N
modules += Git/IndexInfo
modules += Git/Packet
modules += Git/SVN
modules += Git/SVN/Memoize/YAML
modules += Git/SVN/Fetcher

127
t/t0021/rot13-filter.pl
View file

@ -30,9 +30,12 @@
# to the "list_available_blobs" response.
#
use 5.008;
use lib (split(/:/, $ENV{GITPERLLIB}));
use strict;
use warnings;
use IO::File;
use Git::Packet;
my $MAX_PACKET_CONTENT_SIZE = 65516;
my $log_file = shift @ARGV;
@ -55,89 +58,30 @@ sub rot13 {
return $str;
}
sub packet_bin_read {
my $buffer;
my $bytes_read = read STDIN, $buffer, 4;
if ( $bytes_read == 0 ) {
# EOF - Git stopped talking to us!
print $debug "STOP\n";
exit();
}
elsif ( $bytes_read != 4 ) {
die "invalid packet: '$buffer'";
}
my $pkt_size = hex($buffer);
if ( $pkt_size == 0 ) {
return ( 1, "" );
}
elsif ( $pkt_size > 4 ) {
my $content_size = $pkt_size - 4;
$bytes_read = read STDIN, $buffer, $content_size;
if ( $bytes_read != $content_size ) {
die "invalid packet ($content_size bytes expected; $bytes_read bytes read)";
}
return ( 0, $buffer );
}
else {
die "invalid packet size: $pkt_size";
}
}
sub packet_txt_read {
my ( $res, $buf ) = packet_bin_read();
unless ( $buf eq '' or $buf =~ s/\n$// ) {
die "A non-binary line MUST be terminated by an LF.";
}
return ( $res, $buf );
}
sub packet_bin_write {
my $buf = shift;
print STDOUT sprintf( "%04x", length($buf) + 4 );
print STDOUT $buf;
STDOUT->flush();
}
sub packet_txt_write {
packet_bin_write( $_[0] . "\n" );
}
sub packet_flush {
print STDOUT sprintf( "%04x", 0 );
STDOUT->flush();
}
print $debug "START\n";
$debug->flush();
( packet_txt_read() eq ( 0, "git-filter-client" ) ) || die "bad initialize";
( packet_txt_read() eq ( 0, "version=2" ) ) || die "bad version";
( packet_bin_read() eq ( 1, "" ) ) || die "bad version end";
packet_initialize("git-filter", 2);
packet_txt_write("git-filter-server");
packet_txt_write("version=2");
packet_flush();
my %remote_caps = packet_read_and_check_capabilities("clean", "smudge", "delay");
packet_check_and_write_capabilities(\%remote_caps, @capabilities);
( packet_txt_read() eq ( 0, "capability=clean" ) ) || die "bad capability";
( packet_txt_read() eq ( 0, "capability=smudge" ) ) || die "bad capability";
( packet_txt_read() eq ( 0, "capability=delay" ) ) || die "bad capability";
( packet_bin_read() eq ( 1, "" ) ) || die "bad capability end";
foreach (@capabilities) {
packet_txt_write( "capability=" . $_ );
}
packet_flush();
print $debug "init handshake complete\n";
$debug->flush();
while (1) {
my ( $command ) = packet_txt_read() =~ /^command=(.+)$/;
my ( $res, $command ) = packet_required_key_val_read("command");
if ( $res == -1 ) {
print $debug "STOP\n";
exit();
}
print $debug "IN: $command";
$debug->flush();
if ( $command eq "list_available_blobs" ) {
# Flush
packet_bin_read();
packet_compare_lists([1, ""], packet_bin_read()) ||
die "bad list_available_blobs end";
foreach my $pathname ( sort keys %DELAY ) {
if ( $DELAY{$pathname}{"requested"} >= 1 ) {
@ -161,16 +105,14 @@ sub packet_flush {
$debug->flush();
packet_txt_write("status=success");
packet_flush();
}
else {
my ( $pathname ) = packet_txt_read() =~ /^pathname=(.+)$/;
} else {
my ( $res, $pathname ) = packet_required_key_val_read("pathname");
if ( $res == -1 ) {
die "unexpected EOF while expecting pathname";
}
print $debug " $pathname";
$debug->flush();
if ( $pathname eq "" ) {
die "bad pathname '$pathname'";
}
# Read until flush
my ( $done, $buffer ) = packet_txt_read();
while ( $buffer ne '' ) {
@ -184,6 +126,9 @@ sub packet_flush {
( $done, $buffer ) = packet_txt_read();
}
if ( $done == -1 ) {
die "unexpected EOF after pathname '$pathname'";
}
my $input = "";
{
@ -194,6 +139,9 @@ sub packet_flush {
( $done, $buffer ) = packet_bin_read();
$input .= $buffer;
}
if ( $done == -1 ) {
die "unexpected EOF while reading input for '$pathname'";
}
print $debug " " . length($input) . " [OK] -- ";
$debug->flush();
}
@ -201,17 +149,13 @@ sub packet_flush {
my $output;
if ( exists $DELAY{$pathname} and exists $DELAY{$pathname}{"output"} ) {
$output = $DELAY{$pathname}{"output"}
}
elsif ( $pathname eq "error.r" or $pathname eq "abort.r" ) {
} elsif ( $pathname eq "error.r" or $pathname eq "abort.r" ) {
$output = "";
}
elsif ( $command eq "clean" and grep( /^clean$/, @capabilities ) ) {
} elsif ( $command eq "clean" and grep( /^clean$/, @capabilities ) ) {
$output = rot13($input);
}
elsif ( $command eq "smudge" and grep( /^smudge$/, @capabilities ) ) {
} elsif ( $command eq "smudge" and grep( /^smudge$/, @capabilities ) ) {
$output = rot13($input);
}
else {
} else {
die "bad command '$command'";
}
@ -220,25 +164,21 @@ sub packet_flush {
$debug->flush();
packet_txt_write("status=error");
packet_flush();
}
elsif ( $pathname eq "abort.r" ) {
} elsif ( $pathname eq "abort.r" ) {
print $debug "[ABORT]\n";
$debug->flush();
packet_txt_write("status=abort");
packet_flush();
}
elsif ( $command eq "smudge" and
} elsif ( $command eq "smudge" and
exists $DELAY{$pathname} and
$DELAY{$pathname}{"requested"} == 1
) {
$DELAY{$pathname}{"requested"} == 1 ) {
print $debug "[DELAYED]\n";
$debug->flush();
packet_txt_write("status=delayed");
packet_flush();
$DELAY{$pathname}{"requested"} = 2;
$DELAY{$pathname}{"output"} = $output;
}
else {
} else {
packet_txt_write("status=success");
packet_flush();
@ -258,8 +198,7 @@ sub packet_flush {
print $debug ".";
if ( length($output) > $MAX_PACKET_CONTENT_SIZE ) {
$output = substr( $output, $MAX_PACKET_CONTENT_SIZE );
}
else {
} else {
$output = "";
}
}