mirror of
https://github.com/git/git.git
synced 2024-11-18 06:54:55 +01:00
73c6b3575b
* 'master' of git://repo.or.cz/git-gui: (28 commits) git-gui 0.16 git-gui: handle shell script text filters when loading for blame. git-gui: Set both 16x16 and 32x32 icons on X to pacify Xming. git-gui: added config gui.gcwarning to disable the gc hint message git-gui: set whitespace warnings appropriate to this project git-gui: don't warn for detached head when rebasing git-gui: make config gui.warndetachedcommit a boolean git-gui: add config value gui.diffopts for passing additional diff options git-gui: sort the numeric ansi codes git-gui: support underline style when parsing diff output git-gui: fix spelling error in sshkey.tcl git-gui: include the file path in guitools confirmation dialog git-gui: span widgets over the full file output area in the blame view git-gui: use a tristate to control the case mode in the searchbar git-gui: set suitable extended window manager hints. git-gui: fix display of path in browser title git-gui: enable the smart case sensitive search only if gui.search.smartcase is true git-gui: catch invalid or complete regular expressions and treat as no match. git-gui: theme the search and line-number entry fields on blame screen git-gui: include the number of untracked files to stage when asking the user ...
81 lines
1.3 KiB
Tcl
81 lines
1.3 KiB
Tcl
# goto line number
|
|
# based on code from gitk, Copyright (C) Paul Mackerras
|
|
|
|
class linebar {
|
|
|
|
field w
|
|
field ctext
|
|
|
|
field linenum {}
|
|
|
|
constructor new {i_w i_text args} {
|
|
global use_ttk NS
|
|
set w $i_w
|
|
set ctext $i_text
|
|
|
|
${NS}::frame $w
|
|
${NS}::label $w.l -text [mc "Goto Line:"]
|
|
tentry $w.ent \
|
|
-textvariable ${__this}::linenum \
|
|
-background lightgreen \
|
|
-validate key \
|
|
-validatecommand [cb _validate %P]
|
|
${NS}::button $w.bn -text [mc Go] -command [cb _goto]
|
|
|
|
pack $w.l -side left
|
|
pack $w.bn -side right
|
|
pack $w.ent -side left -expand 1 -fill x
|
|
|
|
eval grid conf $w -sticky we $args
|
|
grid remove $w
|
|
|
|
trace add variable linenum write [cb _goto_cb]
|
|
bind $w.ent <Return> [cb _goto]
|
|
bind $w.ent <Escape> [cb hide]
|
|
|
|
bind $w <Destroy> [list delete_this $this]
|
|
return $this
|
|
}
|
|
|
|
method show {} {
|
|
if {![visible $this]} {
|
|
grid $w
|
|
}
|
|
focus -force $w.ent
|
|
}
|
|
|
|
method hide {} {
|
|
if {[visible $this]} {
|
|
$w.ent delete 0 end
|
|
focus $ctext
|
|
grid remove $w
|
|
}
|
|
}
|
|
|
|
method visible {} {
|
|
return [winfo ismapped $w]
|
|
}
|
|
|
|
method editor {} {
|
|
return $w.ent
|
|
}
|
|
|
|
method _validate {P} {
|
|
# only accept numbers as input
|
|
string is integer $P
|
|
}
|
|
|
|
method _goto_cb {name ix op} {
|
|
after idle [cb _goto 1]
|
|
}
|
|
|
|
method _goto {{nohide {0}}} {
|
|
if {$linenum ne {}} {
|
|
$ctext see $linenum.0
|
|
if {!$nohide} {
|
|
hide $this
|
|
}
|
|
}
|
|
}
|
|
|
|
}
|